Why am I getting lifted/5.1 undefined error while using formlets?

Question

I am having trouble with an error I keep getting while trying to use formlets in racket. It says:

; lifted/5.1: undefined;
;  cannot reference an identifier before its definition
;   in module: top-level
;   internal name: lifted/5.1

Nothing in my code is named "lifted" or "5.1" or any combination of the two. I am thinking that this is something inside the black box of formlets that I'm running up against, but I don't know what.

; set up
(require web-server/servlet web-server/servlet-env)
(require web-server/formlets)

; body of program
(define simpleformlet 
   (formlet 
     (#%#
       "Name: " ,{input-string . => . name}
       "Number: " ,{input-int . => . number})
       (name number)))

(define (start request)
  (showpage request))

(define (showpage request)
  (define (responsegen embed/url)
    (response/xexpr
      `(html
         (head (title "App3"))
         (body (h1 "Let's try this...")
               (form
                 ([action ,(embed/url actionhandler)] 
                  [method "POST"])
                 ,@(formlet-display simpleformlet)
                 (input ([type "submit"])))))))

  (define (actionhandler request)
    (define-values (name number)
               (formlet-process simpleformlet request))
    (response/xexpr
      `(html
         (head (title "Alright!"))
         (body (h2 "name")
               (p ,name)
               (h2 "number")
               (p ,number)))))
  (send/suspend/dispatch responsegen))

; run it!
(serve/servlet start
    #:servlet-regexp #rx""
    #:servlet-path "/form")

Answer 1

I added the line

#lang racket

at the top of your program. Used "Determine language from source" in the lower, left corner of DrRacket. And ran your program. A browser window opened and I was able to enter a name and a number, before I got a sensible error.

I am using Racket version 6.12, so if you are using an older version of Racket, then upgrade and try again.