LISP - Program to search a specific function through its parameters

Question

For a course project I got to write a program in lisp.

The program should contain the most important lisp functions, their input and output parameters and maybe optional parameters.

For example: function - first, input - list, output - object (first member of list).

The program should work in 2 different ways:

1. You give the program the name of a function and it should return the function parameters.

2. You enter function parameters and if a function with these parameters exists, it should return the name of the function.

My questions:

1. What would be the right way to approach a task like this in lisp? I think maybe a tree would be a way to handle it? (make a tree with all functions and parameters and then write a program which handles it).

2. Does anyone have a better idea than that to approach this task? Or some suggestions where / how to start? Or Tutorials containing any info?

At the moment I'm a little lost how to start. Any help you can give would be highly appreciated.

English isn't my first language, so I hope everything is understandable.

Greetings.

Answer 1

First of all take a look to prepare your common lisp development environment. After that I think that you should, investigate:

• create functions with defun,

• declare types.

and things like that. Ffter that take a look to two common lisp functions:

• documentation
• describe

Here is a little example:

CL-USER> (defun my-sum (a b) "Add my-sum parameters A and B." (+ a b))
MY-SUM
CL-USER> (my-sum 2 3)
5 (3 bits, #x5, #o5, #b101)
CL-USER> (describe #'my-sum)
#<FUNCTION MY-SUM>
  [compiled function]


Lambda-list: (A B)
Derived type: (FUNCTION (T T) (VALUES NUMBER &OPTIONAL))
Documentation:
  Add my-sum parameters A and B.
Source form:
  (SB-INT:NAMED-LAMBDA MY-SUM
      (A B)
    "Add my-sum parameters A and B."
    (BLOCK MY-SUM (+ A B)))
; No values
CL-USER> (documentation 'my-sum 'function)
"Add my-sum parameters A and B."
CL-USER> (defun my-sum (a b) "Add my-sum parameters A and B." (declare (type fixnum a b)) (+ a b))
WARNING: redefining COMMON-LISP-USER::MY-SUM in DEFUN
MY-SUM
CL-USER> (describe #'my-sum)
#<FUNCTION MY-SUM>
  [compiled function]


Lambda-list: (A B)
Derived type: (FUNCTION (FIXNUM FIXNUM)
               (VALUES
                (INTEGER -9223372036854775808 9223372036854775806)
                &OPTIONAL))
Documentation:
  Add my-sum parameters A and B.
Source form:
  (SB-INT:NAMED-LAMBDA MY-SUM
      (A B)
    "Add my-sum parameters A and B."
    (DECLARE (TYPE FIXNUM A B))
    (BLOCK MY-SUM (+ A B)))
; No values

Finally, one last tip to work with strings from the output of describe:

CL-USER> (with-output-to-string (*standard-output*)
               (describe #'my-sum))
"#<FUNCTION MY-SUM>
  [compiled function]


Lambda-list: (A B)
Derived type: (FUNCTION (FIXNUM FIXNUM)
               (VALUES
                (INTEGER -9223372036854775808 9223372036854775806)
                &OPTIONAL))
Documentation:
  Add my-sum parameters A and B.
Source form:
  (SB-INT:NAMED-LAMBDA MY-SUM
      (A B)
    \"Add my-sum parameters A and B.\"
    (DECLARE (TYPE FIXNUM A B))
    (BLOCK MY-SUM (+ A B)))
"

Answer 2

At face value, the task seems to be the construction of a simple symbolic database in memory, which is searchable in two ways. Entries in the database are understood to be functions. The "output parameters" can probably be understood as one or more return values. These things are not named in ANSI Lisp. A useful interpretation of the task is to give return values symbolic labels anyway. Moreover, we can perhaps use type symbols for the return values as well as parameters. So for instance, a database entry for the cons function might look like:

(cons (t t) cons)   ;; function named cons takes two objects, returns a cons

The type t is the supertype of all types in ANSI Lisp; it means "any value".

A list of such records can be put into some global variable. Then we write a function that is perhaps named get-params-by-name such that:

(get-params-by-name 'cons) -> (t t)

and another one: get-names-by-params:

(get-names-by-params '(t t)) -> (cons)

This function returns all the matching functions, as a list. More than one function could have this signature.

The trick is then finding a good representation of optional and rest parameters. It could just be the same notation that the language uses:

(list (&rest t) list)   ;; list takes rest arguments of any type, returns list

Since we are only interested in exact matches, we don't have to actually parse the &rest notation. When the user queries by parameter, their query object will be literally (&rest t), in that same syntax.

The equal function can be used to tell whether two lists of symbols are identical:

(equal '(&rest t) '(&rest t)) -> t
(equal '(t t) '(t t)) -> nil

So the exercise is not difficult: just mapping through lists, looking for matches.

(defun get-name-by-params (database params)
  (let ((matching-entries (remove-if-not (lambda (entry)
                                            (equal (second entry) params))
                                          database)))
    (mapcar #'first matching-entries))) ;; just the names, please

Here, the function takes the database list as a parameter, instead of referring to a global variable. The overall program into which we integrate this can provide alternative interfaces, but this is our low-level lookup function.

Test:

[1]> (get-name-by-params '((cons (t t) cons) (list (&rest t) list)) '(integer string))
NIL
[3]> (get-name-by-params '((cons (t t) cons) (list (&rest t) list)) '(t t))
(CONS)
[4]> (get-name-by-params '((cons (t t) cons) (list (&rest t) list)) '(&rest t))
(LIST)

I'd get clarification from the instructor whether this is the right interpretation of the vague requirements, before the assignment is due.

Answer 3

Given that this is a course project I'm going to provide an incomplete answer, and leave you to fill in the blanks.

What the program should do

My interpretation of what you're being asked to do is to provide a utility which will

• given the name of a function return its argument list (called a 'lambda list' below);
• given a lambda list return all the functions with that lambda list.

So, first of all you need to decide whether two lambda lists are the same or not. As an example is (x) the same as (y), as a lambda list? Yes, it is: the names of formal parameters only matter in the implementation of a function and you generally won't know them: both of these lambda lists mean 'function of one argument'.

The interestring thing is optional arguments of various kinds: (a &optional b) is clearly not the same as (a), but is the same as (b &optional c) but is it the same as (a &optional (b 1 bp))? In this code I say that yes, it is the same: default values and present parameters for optional arguments don't alter whether lambda lists are the same. That's because very often these are implementation details of functions.

A package

We'll put it into a package so it's clear what the interface is:

(defpackage :com.stackoverflow.lisp.fdesc-search
  (:use :cl)
  (:export
   #:defun/recorded
   #:record-function-description
   #:clear-recorded-functions
   #:name->lambda-list
   #:lambda-list->names))

(in-package :com.stackoverflow.lisp.fdesc-search)

Recording information

So, to start with we need a mechanism of recording information about functions. We'll do this with a macro which is like defun but records information, which I'll call defun/recorded. We want to be able to record information about things even before the program exists & we do this by having defun/recorded stash 'pending' records on a list which, once the program exists, it will pull off and record properly. That lets us use defun/recorded throughout this code.

;;; These define whether there is a recorder, and if not where pending
;;; records should be stashed
;;;
(defvar *function-description-recorder* nil)
(defvar *pending-function-records* '())

(defmacro defun/recorded (name lambda-list &body forms)
  "Like DEFUN but record function information."
  ;; This deals with bootstrapping by, if there is not yet a recording
  ;; function, stashing pending records in *PENDING-FUNCTION-RECORDS*,
  ;; which gets replayed into the recorder at the point it becomes
  ;; available.
  `(progn
     ;; do the DEFUN first, which ensures that the LAMBDA-LIST is OK
     (defun ,name ,lambda-list ,@forms)
     (if *function-description-recorder*
         (progn
           (dolist (p (reverse *pending-function-records*))
             (funcall *function-description-recorder*
                      (car p) (cdr p)))
           (setf *pending-function-records* '())
           (funcall *function-description-recorder*
                    ',name ',lambda-list))
       (push (cons ',name ',lambda-list)
             *pending-function-records*))
     ',name))

Matching lambda lists, first steps

Now we want to be able to match lambda lists. Since we're obviously going to store things indexed by lambda list in some kind of tree we only really need to be able to deal with matching elements of them. And (see above) we don't care about things like default values. I've chosen to do this by first of all simplifying lambda lists to remove them and then matching the simplifies elements: there are other approaches.

simplify-lambda-list does the simplification and argument-matches-p tells you if two arguments match: the interesting bit is that it needs to know about lambda list keywords, which must match exactly, while everything else matches anything. The lambda-list-keywords constant is conveniently provided by the CL standard.

(defun/recorded simplify-lambda-list (ll)
  ;; Simplify a lambda list by replacing optional arguments with inits
  ;; by their names.  This does not validate the list
  (loop for a in ll
        collect (etypecase a
                  (symbol a)
                  (list (first a)))))

(defun/recorded argument-matches-p (argument prototype)
  ;; Does an argument match a prototype.
  (unless (symbolp argument)
    (error "argument ~S isn't a symbol" argument))
  (unless (symbolp prototype)
    (error "prototype ~S isn't a symbol" prototype))
  (if (find-if (lambda (k)
                 (or (eq argument k) (eq prototype k)))
               lambda-list-keywords)
      (eq argument prototype)
    t))

Function descriptions (partial)

Information about functions is stored in objects called fdescs: the definition of these objects is not given here, but one question we need to answer is 'do two fdescs refer to versions of the same function?' Well, they do if the names of the functions are the same. Remember that function names do not have to be symbols ((defun (setf x) (...) ...) is allowed), so we must compare with equal not eql:

(defun/recorded fdescs-equivalent-p (fd1 fd2)
  ;; do FD1 & FD2 refer to the same function?
  (equal (fdesc-name fd1)
         (fdesc-name fd2)))

Storing fdescs indexed by lambda list (partial)

To index things efficiently by lambda list we build a tree. The nodes in this tree are called lambda-list-tree-nodes and their definition is not given here.

There are functions which intern a fdesc in a tree, and which return a list of fdescs indexed by a given lambda list. Neither have an implementation here, but this is what they look like:

(defun/recorded intern-lambda-list (lambda-list tree-node fdesc)
  ;; return the node where it was interned
  ...)

(defun/recorded lambda-list-fdescs (lambda-list tree-node)
  ;; Return a list of fdescs for a lambda list & T if there were any
  ;; or NIL & NIL if there were not (I don't think () & T is possible,
  ;; but it might be in some future version)
  ...)

The implementation of these functions will probably need to use use argument-matches-p and fdescs-equivalent-p.

The top-level databases (slightly partial)

Now we can define the top-level database objects: the root of the tree for indexing by lambda list, and a hashtable for indexing by name

(defvar *lambda-list-tree* (make-lambda-list-tree-node))

(defvar *tree-nodes-by-name* (make-hash-table :test #'equal))

Note that *tree-nodes-by-name* maps from names to the node where the information about that function is stored: that's done to make redefinition easier, as seen in the following function:

(defun/recorded record-function-description (name lambda-list)
  "Record information about a function called NAME with lambda list LAMBDA-LIST.
Replace any existing information abot NAME.  Return NAME."
  (let ((fdesc (make-fdesc :name name :lambda-list lambda-list)))
    ;; First of all remove any existing information
    (multiple-value-bind (node foundp) (gethash name *tree-nodes-by-name*)
      (when foundp
        (setf (lambda-list-tree-node-values node)
              (delete fdesc (lambda-list-tree-node-values node)
                      :test #'fdescs-equivalent-p))))
    (setf (gethash name *tree-nodes-by-name*)
          (intern-lambda-list lambda-list *lambda-list-tree* fdesc)))
  name)

Note that this function first of all looks up any existing information for name, and if it exists it removes it from the node where it was found. This makes sure that function redefinition does not leave obsolete information in the tree.

This function is the actual recorder which defun/recorded wants to know about, so tell it that:

(setf *function-description-recorder*
      #'record-function-description)

Now the next time we invoke defun/recorded it will bootstrap the system by inserting all the the pending definitions.

record-function-description is part of the API to the package: it can be used to record information about functions we don't define.

User-interface functions

Apart from defun/recorded & record-function-description we want some functions which let us make enquiries into the database, as well as one which resets things:

(defun/recorded clear-recorded-functions ()
  "Clear function description records.  Return no values"
  (setf *lambda-list-tree* (make-lambda-list-tree-node)
        *tree-nodes-by-name* (make-hash-table :test #'equal))
  (values))

(defun/recorded name->lambda-list (name)
  "Look up a function by name.
Return either its lambda list & T if it is found, or NIL & NIL if not."
  (multiple-value-bind (node foundp) (gethash name *tree-nodes-by-name*)
    (if foundp
        (values
         (fdesc-lambda-list
          (find-if (lambda (fd)
                     (equal (fdesc-name fd) name))
                   (lambda-list-tree-node-values node)))
         t)
      (values nil nil))))

(defun/recorded lambda-list->names (lambda-list)
  "find function names matching a lambda-list.
Return a list of name & T if there are any, or NIL & NIL if none.

Note that lambda lists are matched so that argument names do not match, and arguments with default values or presentp parameters match just on the argument."
  (multiple-value-bind (fdescs foundp) (lambda-list-fdescs lambda-list 
                                                           *lambda-list-tree*)
    (if foundp
        (values (mapcar #'fdesc-name fdescs) t)
      (values nil nil))))

And that's it.

Examples

After compiling, loading & using the package (with the missing bits added) we can first inject some useful extra functions into it (this is just a random scattering)

> (dolist (x '(car cdr null))
    (record-function-description x '(thing)))
nil

> (dolist (x '(car cdr))
    (record-function-description `(setf ,x) '(new thing)))
nil

> (record-function-description 'cons '(car cdr))
cons

> (record-function-description 'list '(&rest args))

Now we can make some enquiries:

 > (lambda-list->names '(x))
 (null cdr
       car
       lambda-list->names
       name->lambda-list
       com.stackoverflow.lisp.fdesc-search::simplify-lambda-list)
t

> (lambda-list->names '(&rest anything))
(list)
t
 > (name->lambda-list 'cons)
 (car cdr)
 t

---

An example of storing things in trees

Below is some code which demonstrates one approach to storing information in trees (often known as tries). This is not usable above for a lot of reasons, but reading it might help implement the missing parts.

;;;; Storing things in trees of nodes
;;;

;;; Node protocol
;;;
;;; Nodes have values which may or may not be bound, and which may be
;;; assigned.  Things may be interned in (trees of) nodes with a
;;; value, and the value associated with a thing may be retrieved
;;; along with an indicator as to whether it is present in the tree
;;; under the root.
;;;

(defgeneric node-value (node)
  ;; the immediate value of a node
  )

(defgeneric (setf node-value) (new node)
  ;; Set the immediate value of a node
  )

(defgeneric node-value-boundp (node)
  ;; Is a node's value bound?
  )

(defgeneric intern-thing (root thing value)
  ;; intern a thing in a root, returning the value
  (:method :around (root thing value)
   ;; Lazy: this arround method just makes sure that primary methods
   ;; don't need to beother returning the value
   (call-next-method)
   value))

(defgeneric thing-value (root thing)
  ;; return two values: the value of THING in ROOT and T if is it present, or
  ;; NIL & NIL if not
  )


;;; Implementatation for STRING-TRIE-NODEs, which store strings
;;;
;;; The performance of these will be bad if large numbers of strings
;;; with characters from a large alphabet are stored: how might you
;;; fix this without making the nodes enormous?
;;;

(defclass string-trie-node ()
  ;; a node in a string trie.  This is conceptually some kind of
  ;; special case of an abstract 'node' class, but that doesn't
  ;; actually exist.
  ((children-map :accessor string-trie-node-children-map
                 :initform '())
   (value :accessor node-value)))

(defmethod node-value-boundp ((node string-trie-node))
  (slot-boundp node 'value))

(defmethod intern-thing ((root string-trie-node) (thing string) value)
  ;; intern a string into a STRING-TRIE-NODE, storing VALUE
  (let ((pmax (length thing)))
    (labels ((intern-loop (node p)
               (if (= p pmax)
                   (setf (node-value node) value)
                 (let ((next-maybe (assoc (char thing p) 
                                          (string-trie-node-children-map node)
                                          :test #'char=)))
                   (if next-maybe
                       (intern-loop (cdr next-maybe) (1+ p))
                     (let ((next (cons (char thing p)
                                       (make-instance (class-of node)))))
                       (push next (string-trie-node-children-map node))
                       (intern-loop (cdr next) (1+ p))))))))
      (intern-loop root 0))))

(defmethod thing-value ((root string-trie-node) (thing string))
  ;; Return the value associated with a string in a node & T or NIL &
  ;; NIL if there is no value for this string
  (let ((pmax (length thing)))
    (labels ((value-loop (node p)
               (if (= p pmax)
                   (if (node-value-boundp node)
                       (values (node-value node) t)
                     (values nil nil))
                 (let ((next (assoc (char thing p)
                                    (string-trie-node-children-map node)
                                    :test #'char=)))
                   (if next
                       (value-loop (cdr next) (1+ p))
                     (values nil nil))))))
      (value-loop root 0))))


;;; Draw node trees in LW
;;;

#+LispWorks
(defgeneric graph-node-tree (node))
  (:method ((node string-trie-node))
   (capi:contain
    (make-instance 'capi:graph-pane
                   :roots `((nil . ,node))
                   :children-function (lambda (e)
                                        (string-trie-node-children-map (cdr e)))
                   :edge-pane-function (lambda (pane parent child)
                                         (declare (ignore pane parent))
                                         (make-instance
                                          'capi:labelled-line-pinboard-object
                                          :text (format nil "~A" (car child))))
                   :print-function (lambda (n)
                                     (let ((node (cdr n)))
                                       (format nil "~A"
                                               (if (node-value-boundp node)
                                                   (node-value node)
                                                 ""))))))))