Delphi OpenTools API: How to get AfterCompile notifications?

Question

The OpenTools API defines an interface for being notified before and after a compile:

IOTAIDENotifier = interface(IOTANotifier)
  ['{E052204F-ECE9-11D1-AB19-00C04FB16FB3}']
  procedure FileNotification(NotifyCode: TOTAFileNotification; const FileName: string; var Cancel: Boolean);  // This procedure is called for many various file operations within the IDE
  procedure BeforeCompile(const Project: IOTAProject; var Cancel: Boolean); overload; // This function is called immediatately before the compiler is invoked. Set Cancel to True to cancel the compile
  procedure AfterCompile(Succeeded: Boolean); overload; // This procedure is called immediately following a compile.  Succeeded will be true if the compile was successful
end;

i've created a wizard that exports this interface:

TDBGExportWizard = class(TNotifierObject, IOTANotifier, IOTAIDENotifier, IOTAIDENotifier50, IOTAWizard)
public
   { IOTANotifier }
// procedure AfterSave; //This procedure is called immediately after the item is successfully saved. This is not called for IOTAWizards
// procedure BeforeSave; //This function is called immediately before the item is saved. This is not called for IOTAWizard
// procedure Destroyed; // The associated item is being destroyed so all references should be dropped. Exceptions are ignored.
// procedure Modified; // This associated item was modified in some way. This is not called for IOTAWizards

   { IOTAIDENotifier }
   procedure FileNotification(NotifyCode: TOTAFileNotification; const FileName: string; var Cancel: Boolean);
   procedure BeforeCompile(const Project: IOTAProject; var Cancel: Boolean); overload;
   procedure AfterCompile(Succeeded: Boolean); overload;

   { IOTAIDENotifier50 }
   procedure BeforeCompile(const Project: IOTAProject; IsCodeInsight: Boolean; var Cancel: Boolean); overload;
   procedure AfterCompile(Succeeded: Boolean; IsCodeInsight: Boolean); overload;

   { IOTAWizard }
   function GetIDString: string;
   function GetName: string;
   function GetState: TWizardState;
   procedure Execute;
end;

and register the wizard with:

procedure Register;
begin
   RegisterPackageWizard(TDBGExportWizard.Create);
end;

But neither:

• IOTAIDENotifier.BeforeCompile
• IOTAIDENotifier.AfterCompile
• IOTAIDENotifier.FileNotification
• IOTAIDENotifier50.BeforeCompile
• IOTAIDENotifier50.AfterCompile

are called. What am i doing wrong?

---

The only thing ever called is

• IOTAWizard.GetName
• IOTAWizard.GetIDString

In that order.

Answer 1

The following Is from a small piece of our software (I clipped out some code but it should work)

unit UnitSymbolInsert;

interface

procedure Register;

implementation

uses
  SysUtils, ToolsApi, Classes, Types, ActiveX, UnitSymbols;

type
  TCITNotifier = class(TNotifierObject, IOTANotifier, IOTAIDENotifier, IOTAIDENotifier50 )
  protected
    // IOTAIDENotifier
    procedure FileNotification(NotifyCode: TOTAFileNotification; const FileName: string; var Cancel: Boolean);
    procedure BeforeCompile(const Project: IOTAProject; var Cancel: Boolean); overload;
    procedure AfterCompile(Succeeded: Boolean); overload;
    // IOTAIDENotifier50
    procedure BeforeCompile(const Project: IOTAProject; IsCodeInsight: Boolean; var Cancel: Boolean); overload;
    procedure AfterCompile(Succeeded: Boolean; IsCodeInsight: Boolean); overload;
  end;

var
  NotifierIndex: Integer = -1;

procedure Register;
var
  Services: IOTAServices;
begin
  if not Supports(BorlandIDEServices, IOTAServices, Services) then Exit;
  NotifierIndex := Services.AddNotifier(TCITNotifier.Create);
end;

procedure UnRegister;
var
  Services: IOTAServices;
begin
  if (NotifierIndex < 0) or not Supports(BorlandIDEServices, IOTAServices, Services) then Exit;
  Services.RemoveNotifier(NotifierIndex);
end;

{ TCITNotifier }

procedure TCITNotifier.AfterCompile(Succeeded, IsCodeInsight: Boolean);
begin
  // Only when we have a succesfully build for a project.
  if not Succeeded or IsCodeInsight then Exit;

  // do something useful here!!!!
end;

procedure TCITNotifier.BeforeCompile(const Project: IOTAProject; IsCodeInsight: Boolean; var Cancel: Boolean);
begin
  // Not used
end;

procedure TCITNotifier.AfterCompile(Succeeded: Boolean);
begin
  // Not used
end;

procedure TCITNotifier.BeforeCompile(const Project: IOTAProject; var Cancel: Boolean);
begin
  // Not used
end;

procedure TCITNotifier.FileNotification(NotifyCode: TOTAFileNotification; const FileName: string; var Cancel: Boolean);
begin
  // Not used
end;

initialization
  ;
finalization
  UnRegister;
end.

Hopefully I did not clip away too much. Build into a dpk and install it into the IDE.