Why is this fsyacc input producing F# that does not compile?

Question

My fsyacc code is giving a compiler error saying a variable is not found, but I'm not sure why. I was hoping someone could point out the issue.

%{
open Ast
%}


// The start token becomes a parser function in the compiled code:
%start start

// These are the terminal tokens of the grammar along with the types of
// the data carried by each token:
%token NAME
%token ARROW TICK VOID
%token LPAREN RPAREN
%token EOF

// This is the type of the data produced by a successful reduction of the 'start'
// symbol:
%type < Query > start

%%

// These are the rules of the grammar along with the F# code of the 
// actions executed as rules are reduced.  In this case the actions 
// produce data using F# data construction terms.
start: Query { Terms($1) }

Query:
    | Term EOF                  { $1 }

Term: 
    | VOID                      { Void }
    | NAME                      { Conc($1) }
    | TICK NAME                 { Abst($2) }
    | LPAREN Term RPAREN        { Lmda($2) }
    | Term ARROW Term           { TermList($1, $3) }

The line | NAME {Conc($1)} and the following line both give this error:

  error FS0039: The value or constructor '_1' is not defined

I understand the syntactic issue, but what's wrong with the yacc input?

If it helps, here is the Ast definition:

namespace Ast
open System

type Query =
    | Terms   of Term

and Term =
    | Void
    | Conc of String
    | Abst of String
    | Lmda of Term
    | TermList of Term * Term

And the fslex input:

{
module Lexer
open System
open Parser
open Microsoft.FSharp.Text.Lexing

let lexeme lexbuf =
    LexBuffer<char>.LexemeString lexbuf
}

// These are some regular expression definitions
let name = ['a'-'z' 'A'-'Z' '0'-'9']
let whitespace = [' ' '\t' ]
let newline = ('\n' | '\r' '\n')

rule tokenize = parse
| whitespace    { tokenize lexbuf }
| newline       { tokenize lexbuf }
// Operators
| "->"          { ARROW }
| "'"           { TICK }
| "void"        { VOID }
// Misc
| "("           { LPAREN }
| ")"           { RPAREN }
// Numberic constants
| name+                                 { NAME }
// EOF
| eof   { EOF }

Answer 1

This is not FsYacc's fault. NAME is a valueless token.

You'd want to do these fixes:

%token NAME to %token <string> NAME

and

| name+ { NAME } to | name+ { NAME (lexeme lexbuf) }

Everything should now compile.