Send email with attachment in Delphi

Question

How do I send an attachment in an HTML formatted email?

I managed to send an email using stmp.gmail.com in HTML format, but my email has an attachment. The attachment gets converted to a string, but I need it to be in the original file format.

Code:

with FIdSmtp do
begin
  // Configure IdSMTP
end;

FIdMessage.Clear;
FIdMessage.MessageParts.Clear;
FIdMessage.From.Address := 'EmailRemetente';
FIdMessage.From.Name    := 'Apelido';
FIdMessage.Subject      := 'Assunto';
FIdMessage.Body.Text    := 'Mensagem';
FIdMessage.Recipients.EMailAddresses := 'aEmailDestinatario'; //email destino  
FIdMessage.BccList.EMailAddresses := StringReplace(Trim(BCCList.Text),#13#10,',',[rfReplaceAll]);  
FIdMessage.ccList.EMailAddresses := StringReplace(Trim(CCList.Text),#13#10,',',[rfReplaceAll]);
FIdMessage.ContentType := 'text/html';  // set html format

_Anexo := TStringList.Create;
try
  _Anexo.Text := aAnexos;
  for i := 0 to _Anexo.Count - 1 do
    TIdAttachmentFile.Create(FIdMessage.MessageParts,_Anexo.Strings[i]);
finally
  _Anexo.Free
end;    
FIdSmtp.Send(FIdMessage);

Can someone help me?

Answer 1

Read my blog on Indy's website, I discussed this subject in some detail:

HTML Messages

New HTML Message Builder class

With that in mind, try this:

FIdMessage.Clear;
FIdMessage.From.Address := 'EmailRemetente';
FIdMessage.From.Name    := 'Apelido';
FIdMessage.Subject      := 'Assunto';
FIdMessage.Recipients.EMailAddresses := 'aEmailDestinatario';
FIdMessage.BccList.EMailAddresses := StringReplace(Trim(BCCList.Text),sLineBreak,',',[rfReplaceAll]);  
FIdMessage.ccList.EMailAddresses := StringReplace(Trim(CCList.Text),sLineBreak,',',[rfReplaceAll]);
FIdMessage.ContentType := 'multipart/mixed';

with TIdText.Create(FIdMessage.MessageParts, nil) do
begin
  ContentType := 'text/html';
  Body.Text := 'Mensagem';
end;

_Anexo := TStringList.Create;
try
  _Anexo.Text := aAnexos;
  for i := 0 to _Anexo.Count - 1 do
    TIdAttachmentFile.Create(FIdMessage.MessageParts, _Anexo.Strings[i]);
finally
  _Anexo.Free
end;    

Or this:

FIdMessage.Clear;

with TIdMessageBuilderHtml.Create do
try
  Subject := 'Assunto';
  Html.Text := 'Mensagem';

  _Anexo := TStringList.Create;
  try
    _Anexo.Text := aAnexos;
    for i := 0 to _Anexo.Count - 1 do
      Attachments.Add(_Anexo.Strings[i]);
  finally
    _Anexo.Free
  end;
  FillMessage(FIdMessage);
finally
  Free;
end;

FIdMessage.From.Address := 'EmailRemetente';
FIdMessage.From.Name    := 'Apelido';
FIdMessage.Recipients.EMailAddresses := 'aEmailDestinatario'; 
FIdMessage.BccList.EMailAddresses := StringReplace(Trim(BCCList.Text),sLineBreak,',',[rfReplaceAll]);  
FIdMessage.ccList.EMailAddresses := StringReplace(Trim(CCList.Text),sLineBreak,',',[rfReplaceAll]);