Pivot table in kdb+/q

Question

I'm trying to pivot some trade data in KDB/q. Although my data are only slightly different from the working example on the website (see the general pivot function: http://code.kx.com/q/cookbook/pivoting-tables/), I can't get the function to work, even after several hours of trying (I'm very new to KDB).

Put simply, I'm trying to go from this table:

q)5# trades_agg
date       sym  time  exchange buysell| shares
--------------------------------------| ------
2009.01.05 aaca 09:30 BATS     B      | 484
2009.01.05 aaca 09:30 BATS     S      | 434
2009.01.05 aaca 09:30 NASDAQ   B      | 235
2009.01.05 aaca 09:30 NASDAQ   S      | 429
2009.01.05 aaca 09:30 NYSE     B      | 309

to this one:

date       sym  time  | BATSsharesB BATSsharesS NASDAQsharesB    ... 
----------------------| -----------------------------------------------
2009.01.05 aaca 09:30 | 484          434        235              ...
...                   | ... 

I'll provide a working example to illustrate things:

// Create data
qpd:5*2*4*"i"$16:00-09:30
date:raze(100*qpd)#'2009.01.05+til 5
sym:(raze/)5#enlist qpd#'100?`4
sym:(neg count sym)?sym
time:"t"$raze 500#enlist 09:30:00+15*til qpd
time+:(count time)?1000
exchange:raze 500#enlist raze(qpd div 3)#enlist`NYSE`NASDAQ`BATS
buysell:raze 500#enlist raze(qpd div 2)#enlist`B`S
shares:(500*qpd)?100
trades:([]date;sym;time;exchange;buysell;shares)
//I then aggregate the data into equal sized buckets
trades_agg: select sum shares by date, sym, time: 15 xbar time.minute, exchange, buysell from trades

// pivot function from the code.kx.com website
piv:{[t;k;p;v;f;g]
 v:(),v;
 G:group flip k!(t:.Q.v t)k;
 F:group flip p!t p;
 count[k]!g[k;P;C]xcols 0!key[G]!flip(C:f[v]P:flip value flip key F)!raze
  {[i;j;k;x;y]
   a:count[x]#x 0N;
   a[y]:x y;
   b:count[x]#0b;
   b[y]:1b;
   c:a i;
   c[k]:first'[a[j]@'where'[b j]];
   c}[I[;0];I J;J:where 1<>count'[I:value G]]/:\:[t v;value F]}

I subsequently apply this pivot function to the example with the functions f and g set to their default (::) values but I get an error message:

piv[`trades_agg;`date`sym`time;`exchange`buysell;`shares;(::);(::)]

Even when I use the suggested f and g functions it doesn't work:

 f:{[v;P]`$raze each string raze P[;0],'/:v,/:\:P[;1]}
 g:{[k;P;c]k,(raze/)flip flip each 5 cut'10 cut raze reverse 10 cut asc c}

I don't get why this is not working correctly since it is so close to the example on the website.

Answer 1

This is a self-contained version that's easier to use:

tt:1000#0!trades_agg

piv:{[t;k;p;v]
    / controls new columns names
    f:{[v;P]`${raze " " sv x} each string raze P[;0],'/:v,/:\:P[;1]};
     v:(),v; k:(),k; p:(),p; / make sure args are lists
     G:group flip k!(t:.Q.v t)k;
     F:group flip p!t p;
     key[G]!flip(C:f[v]P:flip value flip key F)!raze
      {[i;j;k;x;y]
       a:count[x]#x 0N;
       a[y]:x y;
       b:count[x]#0b;
       b[y]:1b;
       c:a i;
       c[k]:first'[a[j]@'where'[b j]];
       c}[I[;0];I J;J:where 1<>count'[I:value G]]/:\:[t v;value F]};



q)piv[`tt;`date`sym`time;`exchange`buysell;enlist `shares]
date       sym  time | BATS shares B BATS shares S NASDAQ shares B NASDAQ sha..
---------------------| ------------------------------------------------------..
2009.01.05 adkk 09:30| 577           359           499             452       ..
2009.01.05 adkk 09:45| 882           501           339             467       ..
2009.01.05 adkk 10:00| 620           513           411             128       ..
2009.01.05 adkk 10:15| 501           544           272             544       ..
2009.01.05 adkk 10:30| 291           594           363             331       ..
2009.01.05 adkk 10:45| 867           500           498             536       ..
2009.01.05 adkk 11:00| 624           632           694             493       ..
2009.01.05 adkk 11:15| 99            704           600             299       ..
2009.01.05 adkk 11:30| 269           394           280             392       ..
2009.01.05 adkk 11:45| 635           744           758             597       ..
2009.01.05 adkk 12:00| 562           354           498             405       ..
2009.01.05 adkk 12:15| 416           437           303             492       ..
2009.01.05 adkk 12:30| 447           699           370             302       ..
2009.01.05 adkk 12:45| 336           647           512             245       ..
2009.01.05 adkk 13:00| 692           457           497             553       ..

Answer 2

Your table is keyed so unkey it:

trades_agg:0!select sum shares by date, sym, time: 15 xbar time.minute,exchange,buysell from trades

And define your g as:

g:{[k;P;c]k,c}

Best way to figure out what the f/g needs to be is to define it with a breakpoint and then investigate the variables

g:{[k;P;c]break}

Answer 3

I found it difficult to understand the original piv function in Ryan's answer, so I updated it by adding some comments + more readable variable names HTH

piv:{[table; rows; columns; vals]
    
    / make sure args are lists
    vals: (),vals; 
    rows: (),rows;
    columns: (),columns; 

    / Get columns of table corresponding to those of row labels and calculate groups
    / group returns filteredValues dict whose keys are the unique row labels and vals are the row indices of each group e.g. (0 1 3; 2 4; ...)
    rowGroups: group rows#table;
    rowGroupIdxs: value rowGroups;
    rowValues: key[rowGroups];
    
    / Similarly, get columns of table corresponding to those of column labels and calculate groups
    colGroups: group columns#table;
    colGroupIdxs: value colGroups;
    colValues: key colGroups;
    
    getPivotCol: {[rowGroupStartIdx; nonSingleRowGroups; nonSingleRowGroupsIdx; vals; colGroupIdxs]
        / vals: the list of values for this particular value-column combination
        / colGroupIdxs: the list of indices for this particular column group
    
        / We only care about vals that should belong in this pivot column - we need to filter out vals not part of this column group
        filteredValues: count[vals]#vals[0N];
        filteredValues[colGroupIdxs]: vals[colGroupIdxs];
       
        / Equivalent to filteredValues <> 0N
        hasValue: count[vals]#0b;
        hasValue[colGroupIdxs]: 1b;
       
        / Seed off pivot column with the first (filtered) value of each row group
        / This will be correct for row groups of size 1 as no aggregation needs to occur
        pivotCol: filteredValues[rowGroupStartIdx];

        / Otherwise, for the row groups larger than 1, get the first (filtered) value
        pivotCol[nonSingleRowGroupsIdx]: first'[filteredValues[nonSingleRowGroups]@'where'[hasValue[nonSingleRowGroups]]];
        pivotCol
    }
    
    / Groups with more than 1 row (these are the ones that will need aggregating)
    nonSingleRowGroupsIdx: where 1 <> count'[rowGroupIdxs];
    
    / Get resulting pivot column for each combination of column and value fields
    pivotCols: raze getPivotCol[rowGroupIdxs[;0]; rowGroupIdxs[nonSingleRowGroupsIdx]; nonSingleRowGroupsIdx] /:\: [table[vals]; colGroupIdxs]
    
    / Columns names are the cross-product of column and value fields
    colNames:`${raze "" sv vals} each string raze (flip value flip colValues),'/:vals;
    
    / Finally, stitch together row and column headings with pivot data to obtain final table
    rowValues!flip colNames!pivotCols
};

I also made a small change to formatting of columns names for my needs btw