OR match for HTML::TreeBuilder's look_down feature

Question

OR match for HTML::TreeBuilder's look_down feature

726 views Asked by user3689651 At 30 May 2014 at 01:16

Trying to match tr items that have a class with either the first three letters starting with eve or day. This is my attempt:

my @stuff = $p->look_down(
    _tag => 'tr',
    class => 'qr/eve*|day*/g'
);

foreach (@stuff) {
        print $_->as_text;
};

Just curious, what kind of objects are in @stuff?

Is this OK? See below:

my @stuff = $p->look_down(
    _tag => 'tr',
    class => qr/eve.*|day.*/
);

print "\n\n";

foreach (@stuff) {
        print $_->as_text . "\n\n";
};

Original Q&A

There are 1 answers

**Miller** · Answer 1 · 2014-05-30 01:25:09

You need to anchor your regex with ^ in order for the class to match the first three letters.

The following achieves what you want:

use strict;
use warnings;

use HTML::TreeBuilder;

my $p = HTML::TreeBuilder->new_from_content(do {local $/; <DATA>});

foreach my $tr ($p->look_down(_tag => 'tr', class => qr{^(?:eve|day)})) {
    print $tr->as_text, "\n";
};

__DATA__
<html>
<body>
<p>hi</p>
<table>
<tr class="notme"><td colspan=2>row 1 is bad</td></tr>
<tr class="not_eve_or_day"><td colspan=2>row 2 is bad</td></tr>
<tr class="everyrow"><td colspan=2>row 3 is good 1 of 2</td></tr>
<tr class="dayme"><td colspan=2>row 4 is good 2 of 2</td></tr>
<tr class="notme"><td colspan=2>row 5 is bad</td></tr>
</table>
</body>
</html>

Outputs:

row 3 is good 1 of 2
row 4 is good 2 of 2

TechQA.

OR match for HTML::TreeBuilder's look_down feature

There are 1 answers

Related Questions in REGEX

Related Questions in PERL

Related Questions in HTML-TREEBUILDER

Popular Questions

Popular Tags

Trending Questions