Haskell function that applies a list of functions to a list of inputs?

Question

I need a Haskell function that takes a list of functions and a list of elements and applies the functions to the elements like this: the first function to the first element, the second function to the second element, etc. If any of the lists stop, I want the fuction to stop. The difinition I came up with is this:

apply :: [(a -> b)] -> [a] -> [b]

I would like it to work something like this:

apply [(+1), (*3), (^2)] [1,2,3] == [2,6,9]
apply [even, odd] [1..] == [False, False]

Things I tried so far:

apply :: [(a -> b)] -> [a] -> [b]
apply [] _ = []
apply (f:fs) x = (f x) : (apply fs x)

Answer 1

As commented your recursion fails to recurse in the second argument, so the definition would be

apply (f:fs) (x:xs) = (f x) : (apply fs xs) 
apply _      _      = []

You can go point-free with

apply = zipWith ($) -- zipWith id works too as @Redu commented

Or even more interesting, you can go applicativelly-crazy with ZipList

import Control.Applicative
apply f x = getZipList $ ZipList f <*> ZipList x

Answer 2

It's interesting that in two comments are two totally valid answers:

applyAll' :: [b -> c] -> [b] -> [c]
applyAll = zipWith ($)

and

applyAll :: [a -> c] -> [a] -> [c]
applyAll' = zipWith id

It's also interesting that Haskell, due to its way to pick types (type inference), changes a little bit its signature, obviously they are equivalent. id and $ functions are equivalents when id is restricted to functions. (As Robin pointed out in his comment).